Engineer / Solution Architect / Dynamics 365-AX Technical Consultant / Instructor (MCT)

Merhaba

Birinci örnekte metoda gönderilen metinin nokta(). ve tire(-)  haricinde özel karakter içerip içermediğini kontrol ediyoruz.

static boolean isProductNumberValid(EcoResProductNumber _ecoResProductNumber )
{
    Str MatchPattern ="[^a-zA-Z0-9\-.]";
    System.Text.RegularExpressions.Match myMatch;
    ;

    myMatch = System.Text.RegularExpressions.Regex::Match(_ecoResProductNumber,
                                 MatchPattern);

    return !myMatch.get_Success();

}

İkinci örnekte ise gönderilen metindeki özel karakterleri tire(-) ile değiştiriyoruz. Regex ile köşeli parantez “[ ]” ve ters sılaş “\” karakterlerini değiştiremedim. Bu yüzden ax’ın strReplace() metodunu kullanarak değiştirmek zorunda kaldım.

static EcoResProductNumber clearProductNumber(EcoResProductNumber _EcoResProductNumber)
{
    Str                 Pattern =  "[ :;,/+*'@_#!|$½%&(){}^~<> ]";
    EcoResProductNumber ecoResProductNumber;
    ;
ecoResProductNumber =System.Text.RegularExpressions.Regex::Replace(_EcoResProductNumber,
                                                        Pattern, "-");
    ecoResProductNumber = strReplace(ecoResProductNumber ,'[',"-");
    ecoResProductNumber = strReplace(ecoResProductNumber ,']',"-");
    ecoResProductNumber = strReplace(ecoResProductNumber ,'\\',"-");

    return  ecoResProductNumber;
}

Bu metodları Global sınıfına ekledim. Kullanımı çok basit.

static void SEC_FD_RegEx(Args _args)
{
    ;

    if(Global::isProductNumberValid("SEC.s-f.sdf."))
    {
        info("Kod doğru.");
    }

    info(Global::clearProductNumber("SEC D:;,/+*'@_#!|%&(){}^~[] "));
}

Selamlar.

Merhaba

Bir kaç hafta önce Bakırköy’de Toefl sınavına girdim. Gerçekten yorucu bir sınav. 4 saat sürüyor ve sadece 10 dakika ara var. İlk etapla almam gereken notu aldım bir sonraki hedefim 90′ı geçmek. Sınav kesinlikle zor. Çalışmadan iyi bir not almak mümkün değil. Özellikle soru tiplerine çalışmak ve bol bol pratik yapmak lazım.  NoteFull adında bir site var mutlaka incelenmeli. Ücretsiz eğitimler bile çok işinize yarıyor.

Sınav merkezine biraz erken gitmekte fayda var. Form doldurtuyorlar. Daha sonra sınav odasına tek tek çıkıyorsunuz. Resim çekiliyor ve bir numara veriliyor. Her numaraya ait bir kilitli dolay var üzerinizde ne varsa oraya bırakıyorsunuz. Telefon, bilgisayar, saat vs. Masanıza geçtikten sonra öncelikle mikrofon testi yapıyorsunuz.  sonra sınav başlıyor. Reading’de 4 makale geldi hepside gerçekten zordu  çok fazla bilmediğim kelime vardı. Daha sonra Listening başladı. Benim için en kolay kısım burasıydı. En yüksek notu da burada aldım.Dinlerken kafayı benim gibi kağıda gömmeyin ekranda bazı terimler ve resimler oluyor. Gözünüz ekranda olsun. Listeningten sonra 10 dakika ara var. Bir şeyler atıştırmakta gerekiyorsa lavaboya gitmekte fayda var. Daha Sonra Speaking başlıyor. Süreler çok kısa 45 saniye hemen doluyor. Ekrana bakarak konuşmakta fayda. Daha sonra Writing başlıyor birinci soru önce bir makale okuyorsunuz daha sonra bir sınıfta hoca makaledeki fikirlere itiraz ediyor. Size de hocanın makaleye nasıl itiraz ettiği ve ne gerekçeler sunduğunu soruyor. Son soru makale sorusu 300-400 kelimelik bir makale yazmanız gerekiyor. Benim en zayıf olduğum konu bu oldu. Yazma konusunda çok fazla pratiğe ihtiyacım var.

Sonuçlar bir haftada açıklandı.

Selamlar.

Merhaba

Ax 2012′de değişen yapıyla birlikte ortamlar arasında veri transferi biraz sıkıntılı bir durum oldu. Örneğin canlı ortamın veri tabanı yedeğini alıp test ortamına yüklerseniz tamamen eşitlemiş oluyorsunuz. Geliştirmeler temel  ayarlar dahil. Bazen bunu da yapmak isteyebiliriz ama genelde sadece işle alakalı verilerin aktarılmasını isteriz. Bunu yapabilmek için InformationSource’ ta  Test Data Transfer Tool (beta) adında bir araç yayınlandı. Bu araçla ilgili ayrıntılı bilgiyi TechNet‘te bulabilirsiniz. Microsoft bu aracı sadece canlı ortamdan veri aktarmak için kullanmayı tavsiye ediyor. Canlı ortamın kendisine bu aracı kullanarak veri aktarmayı tavsiye etmiyor.

The Test Data Transfer Tool (beta) aşağıdaki durumlar için uygundur.

• Büyük verileri veya birden çok şirketi içeren verileri içeri aktarmak veye dışarı aktarmak için.
• Birbirinden çok farklı olmayan ax ortamları arasında veri aktarımı için.
• Versiyon kontrol sistemi kullanıldığında.
• Microsoft Dynamics AX Application Object Server (AOS) çalışmadan aktarım yapmak gerektiğinde.

The Test Data Transfer Tool (beta) veri aktarımı için Microsoft SQL Server bulk copy tool (bcp)’yi kullanıyor. Bu sayede işlemler SQL server üzerinden daha hızlı yapılabiliyor ve AOS’a ihtiyaç duymuyor. SQL üzerinde bu aktarım yaptığımız için veri bütünlüğü korunur. Örneğin RecID’lerde değişiklik yapmaz aynısını oluşturur.Hangi verinin dışarı aktarılacağı filtrelenebilir.

Aşağıda dışarı aktarım ve içeri aktarım işlemini özetleyen bir grafik var. Burada da görüleceği gibi 3 tane farklı dosya dışarı aktarılıyor. Bu dosyalar text bazlı olduğu için versiyon kontrolü bile yapılabilir.

İçeri aktarım işine mutlaka SQL Server’ın kurulu olduğu makinede admin yetkisiyle yapmak gerekiyor.

Ax 2012 ile veri aktarımı için bir çok alternatif geldi. Bunların hangisi hangi durum için en uygun çözüm olduğunu anlatan bir makaleyi ilerde yazacağım.

Selamlar.

Merhaba

Bu bilgi görseli (infographic) veri depolama aşamalarını gösteriyor. Teknolojinin bu kadar hızla değiştiğini görmek insanı şaşırtıyor. Buluttan sonra bakalım daha neler göreceğiz.

Source : http://blog.systemsadvisers.com

Selamlar.

Hi,

As you know with Dynamics AX 2012, you have to create a product first and then release to the product to companies. You can release which company do you want. In my company there is a request to release product all companies automaticly. I have some research and found good post and methods about it. I wrote a class named SECReleaseProductForAllCompanies and make it MenuItemButton as you can see below.

Let see methods of class now.

Class decleration;

// FD Relaese products for all companies
class SECReleaseProductForAllCompanies
{
    EcoResProductDisplayProductNumber   productNumber;
    EcoResProduct                       ecoResProduct;
}

Main method; Gets all the selected records and calls run.

public static void main(Args args)
{
    SECReleaseProductForAllCompanies    releaseProductForAllCompanies;
    ecoResProduct                       EcoResProduct;
    FormDataSource                      fdsEcoResProduct;
    ;

    fdsEcoResProduct = args.record().dataSource();
    for (EcoResProduct = fdsEcoResProduct.getFirst(true) ? fdsEcoResProduct.getFirst(true) :
            fdsEcoResProduct.cursor();   EcoResProduct; EcoResProduct = fdsEcoResProduct.getnext())
    {
        releaseProductForAllCompanies = new SECReleaseProductForAllCompanies();
        releaseProductForAllCompanies.parmProductNumber(ecoResProduct.DisplayProductNumber);
        releaseProductForAllCompanies.run();

        info(strfmt("%1  %2 product successfully released to all companies. ",
                    EcoResProduct.productNumber() , EcoResProduct.productName() ));
    }
}

Parm method;

public EcoResProductDisplayProductNumber parmProductNumber(
            EcoResProductDisplayProductNumber _productNumber = productNumber)
{
    productNumber = _productNumber;

    return productNumber;
}

Run method;

private void run()
{
    ;
    this.releaseProduct();
}

Release method; You can use EcoResProductReleaseManagerBase::releaseProduct() static method instead of this.

private void releaseProduct()
{
    InventTable                 inventTable;
    InventTableModule           inventTableModule;
    NumberSequenceTable         numberSequenceTable;
    ItemId                      itemId;
    InventItemSetupSupplyType   inventItemSetupSupplyType;
    CompanyInfo                 companyInfo;

    EcoResStorageDimensionGroupProduct  ecoResStorageDimensionGroupProduct;
    EcoResTrackingDimensionGroupProduct ecoResTrackingDimensionGroupProduct;
    EcoResStorageDimensionGroupItem     ecoResStorageDimensionGroupItem;
    EcoResTrackingDimensionGroupItem    ecoResTrackingDimensionGroupItem;
    ;

    select firstOnly ecoResProduct
        where EcoResProduct.DisplayProductNumber == productNumber;

    while select companyInfo
        where companyInfo.DataArea != "DAT"
    {
        changecompany (companyInfo.DataArea)
        {
            ttsBegin;
            inventTable = null;
            inventTableModule = null;
            inventItemSetupSupplyType = null;
            ecoResStorageDimensionGroupProduct = null;
            ecoResTrackingDimensionGroupProduct = null;
            ecoResStorageDimensionGroupItem = null;
            ecoResTrackingDimensionGroupItem = null;

            numberSequenceTable = InventParameters::numRefItemId().numberSequenceTable();

            if (!numberSequenceTable.RecId || numberSequenceTable.Manual)
            {
                itemId = ecoResProduct.productNumber();
            }
            else
            {
                itemId = NumberSeq::newGetNumFromId(numberSequenceTable.RecId).num();
            }

            inventTable.initValue();
            inventTable.initFromEcoResProduct(ecoResProduct);
            inventTable.ItemId = ItemId;
            inventTable.NameAlias = ecoResProduct.SearchName;
            inventTable.insert(true);

            inventTableModule.initValue();
            inventTableModule.ItemId = inventTable.ItemId;
            inventTableModule.ModuleType = ModuleInventPurchSales::Invent;
            inventTableModule.insert();

            inventTableModule.initValue();
            inventTableModule.ItemId = inventTable.ItemId;
            inventTableModule.ModuleType = ModuleInventPurchSales::Purch;
            inventTableModule.insert();

            inventTableModule.initValue();
            inventTableModule.ItemId = inventTable.ItemId;
            inventTableModule.ModuleType = ModuleInventPurchSales::Sales;
            inventTableModule.insert();

            InventItemLocation::createDefault(inventTable.ItemId);

            inventItemSetupSupplyType.initValue();
            inventItemSetupSupplyType.ItemId = inventTable.ItemId;
            inventItemSetupSupplyType.ItemDataAreaId = inventTable.DataAreaId;
            inventItemSetupSupplyType.insert();

            ecoResStorageDimensionGroupProduct  = EcoResStorageDimensionGroupProduct::findByProduct(ecoResProduct.RecId);
            ecoResTrackingDimensionGroupProduct = EcoResTrackingDimensionGroupProduct::findByProduct(ecoResProduct.RecId);

            if (ecoResStorageDimensionGroupProduct.RecId)
            {
                ecoResStorageDimensionGroupItem.ItemDataAreaId = inventTable.DataAreaId;
                ecoResStorageDimensionGroupItem.ItemId = inventTable.ItemId;
                ecoResStorageDimensionGroupItem.StorageDimensionGroup = ecoResStorageDimensionGroupProduct.StorageDimensionGroup;
                ecoResStorageDimensionGroupItem.insert();
            }

            if (ecoResTrackingDimensionGroupProduct.RecId)
            {
                ecoResTrackingDimensionGroupItem.ItemDataAreaId = inventTable.DataAreaId;
                ecoResTrackingDimensionGroupItem.ItemId = inventTable.ItemId;
                ecoResTrackingDimensionGroupItem.TrackingDimensionGroup = ecoResTrackingDimensionGroupProduct.TrackingDimensionGroup;
                ecoResTrackingDimensionGroupItem.insert();
            }

            ttsCommit;

        }
    }
}

You can download class from here.

Thanks Sreenath Reddy G. for methods.

Until next time.